Note
Go to the end to download the full example code.
.geo File: Single Notched Tension Test#
This example demonstrates the procedure for generating a mesh for a single edge notched tension test. Note that Phasefieldx can import external meshes in the .msh format. This can be achieved by using Gmsh.
Files with the .geo format define both the geometry and the mesh parameters, such as element types and sizes. Gmsh can then generate the mesh based on the input from these .geo files.
Below is an example of the .geo file used for mesh generation.
.geo file#
// -----------------------------------------------------------------------------
//
// Gmsh GEO
//
// -----------------------------------------------------------------------------
//Use the following line to generate the mesh (.inp (abaqus))
//gmsh file.geo -3 -o mesh.msh
h = 0.05; //mesh size
hcrack = 0.002; //mesh size near crack
// ------------------------------------------------------
// ------------------------------------------------------
// A)Geometry Definition: 1)Points
// 2)Lines
// 3)Curve
// 4)Surface
// ------------------------------------------------------
// A1)Points Definitions:
//
// P4*----------*P3
// | |
// P5* \ |
// *P7 *P8
// P6* / |
// | |
// P1*----------*P2
//
// |Y
// |
// ---X Dimensions: 1 x 1 x 0.01
// Z /
//
// -----Coordinates--
//Points: ----X,------Y,---Z,
Point(1) ={ -0.5, -0.5, 0, h};
Point(2) ={ 0.5, -0.5, 0, h};
Point(3) ={ 0.5, 0.5, 0, h};
Point(4) ={ -0.5, 0.5, 0, h};
Point(5) ={ -0.5, 0.001, 0, h};
Point(6) ={ -0.5, -0.001, 0, h};
Point(7) ={ 0.0, 0.0, 0, h};
Point(8) ={ 0.5, 0.0, 0, h};
// ------------------------------------------------------
// A2)Lines Definition
//
// <-L3
// *----------*
// |L4| |
// * \L5 | ^
// * |L2
// * /L6 |
// L7| |
// *----------*
// L1->
Line(1) = {1, 2}; //L1:from P1 to P2: P1*--L1-->*P2
Line(2) = {2, 3};
Line(3) = {3, 4};
Line(4) = {4, 5};
Line(5) = {5, 7};
Line(6) = {7, 6};
Line(7) = {6, 1};
// ------------------------------------------------------
// A3)Curve Definition
//
//
// *----<-----*
// | |
// * \ |
// * ^ Curve 5
// * / |
// | |
// *----->----*
//
Curve Loop(5) = {1,2,3,4,5,6,7}; //C5: through lines L1,L2,...,L7
// ------------------------------------------------------
// A4)Surface Definition
//
// *----------*
// | |
// * \ |
// * S6 |
// * / |
// | |
// *----------*
//
Plane Surface(6) = {5}; // Curve loop 5 C5 --> Surface S6
Recombine Surface {6};
// ------------------------------------------------------
// ------------------------------------------------------
// B)Mesh Generation: 1)Mesh size Box1
// 2)Mesh size Box2
// 3)Mesh min(Box1,Box2)
// 3)Extrude Mesh
// 4)Mesh Algorithm
// ------------------------------------------------------
// B1) Mesh size Box1
//
// *----------------*
// | |
// | |
// | |
// * -----------|
// | hcrack F6 | (Field[6])
// * -----------|
// | |
// | |
// | |
// *----------------*
Field[6] = Box;
Field[6].VIn = hcrack;
Field[6].VOut = h;
Field[6].XMin = -0.05;
Field[6].XMax = 0.5;
Field[6].YMin = -0.015;
Field[6].YMax = 0.015;
// ------------------------------------------------------
// B2) Mesh size Box2
//
// *----------------*
// | |
// | |
// | -------------|
// | | |
// * | hcrack*10 |
// * | F7 | (Field[7])
// | | |
// | -------------|
// | |
// | |
// *----------------*
Field[7] = Box;
Field[7].VIn = hcrack*10;
Field[7].VOut = h;
Field[7].XMin = -0.15;
Field[7].XMax = 0.5;
Field[7].YMin = -0.1;
Field[7].YMax = 0.1;
// ------------------------------------------------------
// B3) Mesh min(Box1,Box2)
//
// *----------------*
// | |
// | -------------|
// | | hcrack*10 |
// * | ----------|
// | | | hcrack F8| Field[8]
// * | ----------|
// | | F8|
// | -------------|
// | |
// *----------------*
Field[8] = Min;
Field[8].FieldsList = {6,7};
Background Field = 8;
// ------------------------------------------------------
// B4)Extrude Mesh
// {X, Y, Z} Surface
Extrude{0, 0, 0.01}{Surface{6}; Layers{{1},{1}}; Recombine;}
// ------------------------------------------------------
// B5)Mesh Algorithm
Geometry.Tolerance = 1e-12;
Mesh.SaveAll = 1;
// ------------------------------------------------------
// Physical groups definition
//
// "top"
// *----------*
// | |
// * \ |
// * *
// * / |
// | |
// *----------*
// "bottom"
//
Physical Surface("bottom", 45) = {19};
Physical Surface("top", 46) = {27};
For more information about Gmsh and the .geo file format, please refer to the official Gmsh website.
To generate the mesh in the .msh format from the terminal, use the following Gmsh command:
Here, -3 specifies that the mesh is 3-dimensional, and -o mesh.msh tells Gmsh to save the mesh to a file named mesh.msh with the .msh extension.
Alternatively, you can generate the mesh using the Gmsh Python API, which allows for programmatic mesh generation within Python scripts.
Mesh Visualization#
The purpose of this code is to visualize the mesh. The mesh is generated from the .geo file and saved as output_mesh_for_view.vtu. It is then loaded and visualized using PyVista.
import os
import gmsh
import pyvista as pv
folder = "9101_SingleNotchedTensionTest"
Initialize Gmsh
gmsh.initialize()
Open the .geo file
geo_file = os.path.join(folder, "file.geo")
gmsh.open(geo_file)
Generate the mesh (2D example, for 3D use generate(3))
gmsh.model.mesh.generate(3)
Write the mesh to a .vtk file for visualization Note that the input mesh file for the phasefieldx simulation should have the .msh extension. Use “output_mesh_for_view.msh” to generate the mesh for the simulation input. In this case, the mesh is saved in .vtk format to facilitate visualization with PyVista.
vtu_file = os.path.join(folder, "output_mesh_for_view.vtk")
gmsh.write(vtu_file)
Finalize Gmsh
gmsh.finalize()
print(f"Mesh successfully written to {vtu_file}")
file_vtu = pv.read(vtu_file)
file_vtu.plot(cpos='xy', color='white', show_edges=True)
Mesh successfully written to 9101_SingleNotchedTensionTest/output_mesh_for_view.vtk
Total running time of the script: (0 minutes 0.942 seconds)